import processing.opengl.*;
float nx, ny;       // Posição nave
float [] posXTiro;  // Vetor que armazena a posição x dos tiros
float [] posYTiro;  // Vetor que armazena a posição y dos tiros
float rotacao = 45; // Indica a rotação

void setup() {
  size(600,600,OPENGL);
  smooth();  // anti-aliasint
  noCursor(); // Desliga o cursor
  posXTiro = new float[0];
  posYTiro = new float[0];
}

void atualizarObjetos() {
  // Todos os tiros andam de 10 em 10 pixels
  for(int i=0;i<posXTiro.length;i++) {
    posYTiro[i] = posYTiro[i] - 10;
  }
  // Eliminar tiros muito velhos
  if(posXTiro.length>20) {
     posXTiro = subset(posXTiro, 1);
     posYTiro = subset(posYTiro, 1);
  }
}

// Aqui você vai checar o inimigo
void checarColisoes() {

}

void desenharCenario() {
  pushMatrix();
  pushStyle();
  translate(width/2, height/2);
  rotateX(radians(rotacao));
  for(int i=-200;i<200;i=i+10) {
    for(int j=-600;j<200;j=j+10) {
      fill(255,255,0);
      rect(i,j,9,9);
    }
  }
  popStyle();
  popMatrix();
}

void desenharNave() {
  pushMatrix();
  pushStyle();
  translate(width/2, height/2);
  rotateX(radians(rotacao));
  translate(nx,ny, 20);
  fill(255,0,0);
  box(70,30,30);
  popStyle();
  popMatrix();
}

void desenharTiros() {
  pushMatrix();
  pushStyle(); 
  sphereDetail(10);
  fill(0,0,255);
  noStroke();
  lights();
  translate(width/2, height/2);
  rotateX(radians(rotacao));
  for(int i=0;i<posXTiro.length;i++) {
    pushMatrix();
    translate(posXTiro[i], posYTiro[i], 10);
    sphere(10);
    popMatrix();
  }
  popStyle();
  popMatrix();
}


void desenharObjetos() {
  desenharNave();
  desenharTiros();
}

void checarControles() {
  // Posição da nave é dependente do mouse
  nx = map(mouseX,0, width,-150, 150);
  ny = map(mouseY,0, height,-150, 150);
}

void mousePressed() {
  // Um tiro é criado quando o botão do mouse é pressionado
  posXTiro = append(posXTiro, nx);
  posYTiro = append(posYTiro, ny);
}

void keyPressed() {
  // Rotaciona a tela através do teclado
  if(keyCode==UP) {
    rotacao = rotacao + 1;
  }
  if(keyCode==DOWN) {
    rotacao = rotacao - 1;
  }
}

void draw() {
  // Loop principal
  background(255);
  checarControles();
  atualizarObjetos();
  checarColisoes();
  desenharCenario();
  desenharObjetos();
}